GNU bug report logs - #70203
[PATCH] gnu: tests: Add system tests for sddm

Previous Next

To add a comment to this bug, you must first unarchive it, by sending
a message to control AT debbugs.gnu.org, with unarchive 70203 in the body.
You can then email your comments to 70203 AT debbugs.gnu.org in the normal way.

Toggle the display of automated, internal messages from the tracker.

Message #5 received at submit <at> debbugs.gnu.org (full text, mbox):

From: Richard Sent <richard <at> freakingpenguin.com>
To: guix-patches <at> gnu.org
Cc: Richard Sent <richard <at> freakingpenguin.com>
Subject: [PATCH] gnu: tests: Add system tests for sddm
Date: Thu,  4 Apr 2024 17:21:52 -0400

* gnu/tests/sddm.scm: Create a basic suite of tests to verify the display
manager starts.

Change-Id: Ia84926e9aab42c6781430c22aae0f892387d1a29
---
Hi Guix!

Given https://issues.guix.gnu.org/70194 I figured it was prudent to
create a test suite for SDDM similar to GDM and LightDM.

I verified this on c9cd16c630, since SDDM seems to be broken since at
least 188d18fc47 (probably earlier). I imagine this should go in after
70194 is closed. Or perhaps there's something horribly wrong with my
machine and this does work on master.

Either way, the more tests the merrier, right?

 gnu/tests/sddm.scm | 112 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 112 insertions(+)
 create mode 100644 gnu/tests/sddm.scm

diff --git a/gnu/tests/sddm.scm b/gnu/tests/sddm.scm
new file mode 100644
index 0000000000..87059112ee
--- /dev/null
+++ b/gnu/tests/sddm.scm
@@ -0,0 +1,112 @@
+;;; GNU Guix --- Functional package management for GNU
+;;; Copyright © 2024 Richard Sent <richard <at> freakingpenguin.com>.
+;;;
+;;; This file is part of GNU Guix.
+;;;
+;;; GNU Guix is free software; you can redistribute it and/or modify it
+;;; under the terms of the GNU General Public License as published by
+;;; the Free Software Foundation; either version 3 of the License, or (at
+;;; your option) any later version.
+;;;
+;;; GNU Guix is distributed in the hope that it will be useful, but
+;;; WITHOUT ANY WARRANTY; without even the implied warranty of
+;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;;; GNU General Public License for more details.
+;;;
+;;; You should have received a copy of the GNU General Public License
+;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
+
+(define-module (gnu tests sddm)
+  #:use-module (gnu bootloader)
+  #:use-module (gnu bootloader grub)
+  #:use-module (gnu packages)
+  #:use-module (gnu packages ocr)
+  #:use-module (gnu packages xorg)
+  #:use-module (gnu services)
+  #:use-module (gnu services desktop)
+  #:use-module (gnu services sddm)
+  #:use-module (gnu services xorg)
+  #:use-module (gnu system)
+  #:use-module (gnu system vm)
+  #:use-module (gnu tests)
+  #:use-module (guix gexp)
+  #:use-module (guix modules)
+  #:use-module (srfi srfi-1)
+  #:export (%test-sddm))
+
+(define %sddm-os
+  (operating-system
+    (inherit %simple-os)
+    (services
+     (cons* (service sddm-service-type)
+            (modify-services %desktop-services
+              (delete gdm-service-type))))))
+
+(define (run-sddm-test)
+  "Run tests in %SDDM-OS."
+
+  (define os (marionette-operating-system
+              %sddm-os
+              #:imported-modules (source-module-closure
+                                  '((gnu services herd)))))
+
+  (define vm (virtual-machine
+              (operating-system os)
+              ;; Test may nondeterministically fail with default memory size.
+              (memory-size 1024)))
+
+  (define test
+    (with-imported-modules (source-module-closure
+                            '((gnu build marionette)))
+      #~(begin
+          (use-modules (gnu build marionette)
+                       (srfi srfi-26)
+                       (srfi srfi-64))
+
+          (let ((marionette (make-marionette (list #$vm))))
+
+            (test-runner-current (system-test-runner #$output))
+            (test-begin "sddm")
+
+            (test-assert "service is running"
+              (marionette-eval
+               '(begin
+                  (use-modules (gnu services herd))
+                  ;; sddm's shepherd service is called xorg-server
+                  (start-service 'xorg-server))
+               marionette))
+
+            (test-assert "service can be stopped"
+              (marionette-eval
+               '(begin
+                  (use-modules (gnu services herd))
+                  (stop-service 'xorg-server))
+               marionette))
+
+            (test-assert "service can be restarted"
+              (marionette-eval
+               '(begin
+                  (use-modules (gnu services herd))
+                  (restart-service 'xorg-server))
+               marionette))
+
+            (test-assert "login screen up"
+              ;; GNU Ocrad fails to recognize any text, so use Tesseract.
+              (wait-for-screen-text marionette
+                                    ;; Login button not recognized, use SDDM's
+                                    ;; welcome message.
+                                    (cut string-contains <> (string-append "Welcome to "
+                                                                           #$(operating-system-host-name %sddm-os)))
+                                    #:ocr #$(file-append tesseract-ocr
+                                                         "/bin/tesseract")
+                                    #:timeout 60))
+
+            (test-end)))))
+
+  (gexp->derivation "sddm-test" test))
+
+(define %test-sddm
+  (system-test
+   (name "sddm")
+   (description "Basic tests for the SDDM service.")
+   (value (run-sddm-test))))

base-commit: ade6845da6cec99f3bca46faac9b2bad6877817e
-- 
2.41.0

Message #10 received at 70203-done <at> debbugs.gnu.org (full text, mbox):

From: Christopher Baines <mail <at> cbaines.net>
To: Richard Sent <richard <at> freakingpenguin.com>
Cc: 70203-done <at> debbugs.gnu.org
Subject: Re: [bug#70203] [PATCH] gnu: tests: Add system tests for sddm
Date: Mon, 15 Apr 2024 10:34:23 +0100

[Message part 1 (text/plain, inline)]

Richard Sent <richard <at> freakingpenguin.com> writes:

> * gnu/tests/sddm.scm: Create a basic suite of tests to verify the display
> manager starts.
>
> Change-Id: Ia84926e9aab42c6781430c22aae0f892387d1a29
> ---
> Hi Guix!
>
> Given https://issues.guix.gnu.org/70194 I figured it was prudent to
> create a test suite for SDDM similar to GDM and LightDM.
>
> I verified this on c9cd16c630, since SDDM seems to be broken since at
> least 188d18fc47 (probably earlier). I imagine this should go in after
> 70194 is closed. Or perhaps there's something horribly wrong with my
> machine and this does work on master.
>
> Either way, the more tests the merrier, right?
>
>  gnu/tests/sddm.scm | 112 +++++++++++++++++++++++++++++++++++++++++++++
>  1 file changed, 112 insertions(+)
>  create mode 100644 gnu/tests/sddm.scm

Looks good to me, I've pushed this to master as
027419626f171cdccf9c4a77686840141ea502eb.

Chris

[signature.asc (application/pgp-signature, inline)]

Previous Next

GNU bug tracking system
Copyright (C) 1999 Darren O. Benham, 1997,2003 nCipher Corporation Ltd, 1994-97 Ian Jackson.